这是您可以在 10 分钟内在 Tableau 中获得的东西。

您需要的是甘特图的年份分箱、技能权重和长度（year_end - year_start）：

@init-random 的第一个情节略有不同的是使用Boxplot。这里的TotalSize示例使用相同的设置d

 xy <- boxplot(TotalSize ~ start.decade    ,   
 data =  d,        
 ylab="sum of skill levels", xlab="start.decade", main= "Skill per Decade - TotalSize")

但这实际上忽略了该因素并将其解释为数字。要及时绘制因子频率，您可以使用levelplot将第三维解释为颜色。

 library(lattice)
 library(RColorBrewer)
 library(reshape)

 df <- data.frame(d)
 df <- as.data.frame.matrix(table(df[,c("TotalSize","start.decade")]))
 df$TotalSize <- rownames(df)
 library(reshape)
 dfm <- melt(df, id = c("TotalSize"))
 colnames(dfm) <- c("TotalSize", "decade", "count")
 dfm$decade <- as.factor(dfm$decade)
 dfm$TotalSize <- as.factor(dfm$TotalSize)

 xy <- levelplot(count ~ decade + TotalSize , data=dfm, cuts=8, 
 col.regions=brewer.pal(9,"YlOrRd")  ,   
 ylab="Total Skill", xlab="Decade", main= "Total Skill per Decade")
 print (xy)

你可以做几件不同的事情。

library(data.table)
d <- data.table(read.csv('/tmp/x.csv', sep='\t', quote='', header=T, na.strings=''))
# bucket start date to decade
d[, start.decade:=10*floor(YearFrom/10)]
# create quantiles to represent the inner quartile range
xy.plot <- d[, .(bg1.lower=quantile(BkgArea1, .25),
       bg1.upper=quantile(BkgArea1, .75),
       bg2.lower=quantile(BkgArea2, .25), 
       bg2.upper=quantile(BkgArea2, .75), 
       bg3.lower=quantile(BkgArea3, .25), 
       bg3.upper=quantile(BkgArea3, .75)), by=start.decade]
plot(xy.plot$start.decade, xy.plot$bg1.lower, col='red', type='l')
lines(xy.plot$start.decade, xy.plot$bg1.upper, col='red')
lines(xy.plot$start.decade, xy.plot$bg2.lower, col='green')
lines(xy.plot$start.decade, xy.plot$bg2.upper, col='green')
lines(xy.plot$start.decade, xy.plot$bg3.lower, col='blue')
lines(xy.plot$start.decade, xy.plot$bg3.upper, col='blue')

我觉得这有点乱。你可以一次只展示一对。

马赛克图非常适合分类数据。相对面积是横截面对中的用户密度。将数字更改为文本会更清楚。

mosaicplot(BkgArea1 ~ BkgArea3 + BkgArea2, d[start.decade==2010])

您可以每十年拥有一个或可视化十年的总列，这取决于您想要什么。

更新

从我们在原始帖子中停止的地方开始，可以快速交互式地查看背景区域。我在此处以 gif 文件显示此内容，因为您需要安装免费的 Wolfram CDF 播放器或 Mathematica 才能查看交互性（还有不需要安装的 Wolfram Cloud，但我不希望你们都用完我的云在你玩这个的时候学分）。

控件在 Mathematica 中看起来更好，但 gif 导出使用更简单的表示形式。在任何情况下，您的报告都可以以这种交互式背景视图为开头，并使用包含所有员工的静态表作为附录。您可以在 Mathematica 中编写报告并将其作为 CDF 发送（他们必须安装阅读器）。

数学代码

电话可能看起来很大，Manipulate但它只有两个部分。第一个Grid用于表格，它使用第二个Grid调用中定义的排序变量。

(* Pregroup the data by decade *)
backgroundByDecade = Function[{decade},
      decade -> 
       background[
        Select[IntervalMemberQ[Interval[{#["YearFrom"], #["YearTo"]}],
            decade] &]]
      ] /@ decades // Association // Dataset;

(* Create interactive information grid *)
Manipulate[
 Grid[Transpose[Normal[
    backgroundByDecade[All,
      Function[{bkgDecade},
         Column[
          Normal@bkgDecade[
             SortBy[{firstDesc #[firstCol], secondDesc #[secondCol], 
                thirdDesc #[thirdCol]} &]][All, #["BkgChart"] &], 
          Spacings -> 0]]][KeyValueMap[{#1, #2} &]]
    ]],
  Alignment -> {Center, Top},
  Dividers -> {Gray, {None, {2 -> Gray}}},
  BaseStyle -> {FontFamily -> "Calibri"}],
 Style["Sory By", 14, Bold],
 Grid[{
   {"First", 
    Control[{{firstCol, "BkgArea1", ""}, {"BkgArea1", "BkgArea2", 
       "BkgArea3"}}], 
    Control[{{firstDesc, -1, "Desc",}, {1, -1}, Checkbox}]},
   {"Second", 
    Control[{{secondCol, "BkgArea2", ""}, {"BkgArea1", "BkgArea2", 
       "BkgArea3"}}], 
    Control[{{secondDesc, -1, "Desc"}, {1, -1}, Checkbox}]},
   {"Third", 
    Control[{{thirdCol, "BkgArea3", ""}, {"BkgArea1", "BkgArea2", 
       "BkgArea3"}}], 
    Control[{{thirdDesc, -1, "Desc"}, {1, -1}, Checkbox}]}
   }, Alignment -> Left],
 ControlPlacement -> Left, Paneled -> False
 ]

原帖

据我了解，您希望在每个十年开始时查看一个人的背景区域。

下面使用了每个背景区域的颜色，并且每个颜色都变亮以显示背景的强度/弱点。还给出了背景编号，但如果您愿意，可以将其删除并放置在框的工具提示中。每个框集包含背景区域的 3 个维度。

这些集合排列在每个十年开始的时间列中。背景区域在列内对齐，因此您可以向下扫描十年背景区域以查看其强度在不同人之间的分布。也可以为每个十年列添加摘要背景区域框集。

数学代码

data = Import[FileNameJoin[{NotebookDirectory[], "BackgroundArea.txt"}], "Table"];

(* Background area chart function *)
bkgAreaBarChart[bkgArea1_, bkgArea2_, bkgArea3_] :=
 BarChart[{{1, 1, 1}}, ChartLayout -> "Stacked",
  ChartStyle -> {EdgeForm[Gray], 
    Inner[#1[#2] &, 
     Function[{value}, 
       Nest[Lighter, #, 3 - value]] & /@ {Purple,Orange, Blue}, {bkgArea1, bkgArea2, bkgArea3}, List]}, 
  Axes -> False,
  PlotRangePadding -> None,
  BarOrigin -> Left,
  ChartLabels -> Placed[{bkgArea1, bkgArea2, bkgArea3}, Center],
  BaseStyle -> {Background -> None},
  ImagePadding -> None,
  ImageSize -> {Automatic, 20},
  AspectRatio -> 1/3]

(* Create Dataset from data and add chart column *)
background = Dataset[
  AssociationThread[
     Join[First@data, {"BkgChart"}],
     Join[#, {bkgAreaBarChart[Sequence @@ #[[{2, 3, 4}]]]}]
     ] & /@ Rest@data]

(* Calculate decades from dataset *)
decades = 
 Range[Sequence @@ Normal[background[MinMax, {"YearFrom", "YearTo"}][Round[#, 10] &]], 10]

(* Create information grid *)
Grid[
 Join[
  {Join[{""}, decades]},
  Transpose[
   Join[{background[All, "Person"] // Normal},
    Function[{decade},
      background[All, 
        If[IntervalMemberQ[Interval[{#["YearFrom"], #["YearTo"]}], decade],
          #["BkgChart"], 
          Graphics[ImageSize -> {Automatic, 20},
           AspectRatio -> 1/3]] &] // Normal] /@ decades
    ]],
  {Join[{""}, decades]}
  ],
 Alignment -> {{Left, {Center}}, Center},
 Spacings -> {0, 0},
 Dividers -> {{None, {Gray}}, {None, {2 -> Gray, -2 -> Gray}}},
 Background -> {None, {None, {LightGray, None}, None}},
 BaseStyle -> {FontFamily -> "Calibri"}]

这很有趣。